Group {
  Omega = Region[ 1 ];
  Gamma0 = Region[ 2 ];
  Gamma1 = Region[ 3 ];
}

Constraint { // non-physical, just to follow H6.4...
  { Name u0;
    Case {
      { Region Gamma0; Value 0; }
    }
  }
  { Name u1;
    Case {
      { Region Gamma1; Value 1000 ; }
    }
  }
}

Jacobian {
  { Name JVol;
    Case { { Region All; Jacobian Vol; } }
  }
}

Integration {
  { Name I1;
    Case { { Type Gauss; Case { { GeoElement Triangle; NumberOfPoints  6; } } } }
  }
}

FunctionSpace {
  { Name Hgrad_u; Type Form0; 
    BasisFunction {
      { Name sn1n; NameOfCoef wn1n; Function BF_Node; Support Omega; Entity NodesOf[All]; }
    }
    Constraint {
      { NameOfCoef wn1n; EntityType NodesOf; NameOfConstraint u1; }
      { NameOfCoef wn1n; EntityType NodesOf; NameOfConstraint u0; }
    }
  }
}

Formulation {
  { Name Diffusion; Type FemEquation; 
    Quantity { 
      { Name u; Type Local; NameOfSpace Hgrad_u; }
    }
    Equation {
      Galerkin { [ Dof{Grad u} , {Grad u} ]; 
                 In Omega; Integration I1; Jacobian JVol;  }
      Galerkin { Dt [ Dof{u} , {u} ]; 
                 In Omega; Integration I1; Jacobian JVol;  }
    }
  }
}

Resolution {
  { Name Diffusion;
    System {
      { Name A; NameOfFormulation Diffusion; }
    }
    Operation { 
      InitSolution[A] ; SaveSolution[A] ;
      TimeLoopTheta {
	Time0 0. ; DTime 0.01 ; Theta 1 ; TimeMax 1 ; // Backward Euler
	// Time0 0. ; DTime 0.01 ; Theta 0.5 ; TimeMax 1 ; // Trapezoidal
	Operation { 
	  Generate[A] ; Solve[A] ; SaveSolution[A];
	} 
      } 
    }
  }

}

PostProcessing {
  { Name Diffusion; NameOfFormulation Diffusion;
    Quantity {
      { Name u; Value{ Local{ [ {u} ]; In Omega; Jacobian JVol; } } }
    }
  }
}

PostOperation {
  { Name u; NameOfPostProcessing Diffusion;
    Operation {
      Print[ u , OnElementsOf Omega , File "u.pos"];
    }
  }
}