Group {
  Omega = Region[ 1 ];
  Gamma0 = Region[ 2 ];
  Gamma1 = Region[ 3 ];
}

Function {
  TimeFct[] = Sin[2 * Pi * $Time] ;
}

Constraint {
  { Name u0;
    Case {
      { Region Gamma0; Value 0; }
    }
  }
  { Name u1;
    Case {
      { Region Gamma1; Value Sin[($Y + 1) * Pi / 2]; TimeFunction TimeFct[]; }
    }
  }
}

Jacobian {
  { Name JVol;
    Case { { Region All; Jacobian Vol; } }
  }
}

Integration {
  { Name I1;
    Case { { Type Gauss; Case { { GeoElement Triangle; NumberOfPoints 6; } } } }
  }
}

FunctionSpace {
  { Name Hgrad_u; Type Form0; 
    BasisFunction {
      { Name sn1n; NameOfCoef wn1n; Function BF_Node; Support Omega; Entity NodesOf[All]; }
    }
    Constraint {
      { NameOfCoef wn1n; EntityType NodesOf; NameOfConstraint u1; }
      { NameOfCoef wn1n; EntityType NodesOf; NameOfConstraint u0; }
    }
  }
}

Formulation {
  { Name Wave; Type FemEquation; 
    Quantity { 
      { Name u; Type Local; NameOfSpace Hgrad_u; }
    }
    Equation {
      Galerkin { [ Dof{Grad u} , {Grad u} ]; 
                 In Omega; Integration I1; Jacobian JVol;  }
      Galerkin { DtDt [ Dof{u} , {u} ]; 
                 In Omega; Integration I1; Jacobian JVol;  }
    }
  }

}

Resolution {
  { Name Wave;
    System {
      { Name A; NameOfFormulation Wave; }
    }
    Operation { 
      InitSolution[A] ;
      InitSolution[A] ;
      TimeLoopNewmark{
	Time0 0 ; DTime 0.01 ; Beta 0.25; Gamma 0.5 ; TimeMax 5 ;
	Operation { 
	  Generate[A] ; Solve[A] ; Test[ !($TimeStep % 2) ] { SaveSolution[A] ; }
	} 
      }
    } 
  }
}

PostProcessing {
  { Name Wave; NameOfFormulation Wave;
    Quantity {
      { Name u; Value{ Local{ [ {u} ]; In Omega; Jacobian JVol; } } }
    }
  }
}

PostOperation {
  { Name u; NameOfPostProcessing Wave;
    Operation {
      Print[ u , OnElementsOf Omega , File "u.pos"];
    }
  }
}